Las Reliquias de Tolti Aph
An interactive fiction by Graham Nelson (2005) - the Inform 7 source text
Contents
Previous
Next
Complete text
The Camino de Gravilla is north of the Carril Resquebrajado. "El pavimento provisional llega hasta aquí, donde la calle degenera en un camino de gravilla surcado por carros y pisoteado por infinidad de huellas de pies desnudos extrañamente inhumanos."
Understand "pisa" or "pisotea" as jumping. Instead of jumping in the Camino de Gravilla, say "Saltas sobre la gravilla, y te extrañas de que tus propias huellas tampoco parezcan humanas."
Instead of going nowhere from the Camino de Gravilla, say "Aunque los montículos alrededor del carril - mitad mampostería mitad restos de árboles - debieron ser en su día edificios públicos, ahora son inaccesibles. Quizás más allá hacia el norte."
The camino surcado pisoteado por huellas inhumanas is scenery in the Camino de Gravilla. Understand "grava" or "gravilla" as the camino surcado. The description of the camino surcado is "Trazas círculos en la gravilla surcada con la punta del pié, sin ningún beneficio duradero."
A hostile goblin called Vish is in the Camino de Gravilla. Vish carries a lanza corta. "Vish, un centinela goblin armado con una lanza corta, sisea de rabia simplemente por verte profanando su dominio."
Instead of going to the Vado for the first time, say "Tan sólo una advertencia antes de proceder: quizás debieras ejercitar algo de cautela. Parece ser que la callejuela desciende hacia aguas poco profundas, si los goblins tienen un campamento debe de ser allí."[1]
Vado del Torrente Frigio is north of the Camino de Gravilla. "Un rápido torrente poco profundo pasa por la calle desde el noroeste hacia el sureste, y no es ningún riachuelo del bosque, por lo que sienten tus tobillos, más bien parece el nacimiento de un río de montaña que debe de haber brotado del suelo a menos de un kilómetro de aquí. Esto debe de ser trabajo de los goblins."
Filling is an action applying to one visible thing.
Understand "llena [something]" as filling.
Report filling: say "aquí no hay agua para llenar."
In Vado del Torrente Frigio are four goblins, a manojo de ramitas and a puchero roto. The manojo is madera. The puchero is arcilla. Instead of filling the puchero, say "Agj. ¿Usar un puchero que los goblins han usado para cocinar? Mejor no." Instead of burning the manojo, say "El manojo de ramitas está demasiado húmedo para que el fuego agarre, incluso si tuvieses algo con que encenderlo. Los goblins [italic type]han[roman type] descubierto el fuego, pero siguen olvidándose de los puntos esenciales." Effect of casting remendar at the puchero: record outcome "pero es que el puchero no está roto, así tal cual; es que sencillamente fue mal hecho desde primera instancia"; rule succeeds.
A thing called Torrente Frigio is a backdrop. The Torrente Frigio is in the Vado del Torrente Frigio, the Vertiente and the Nacimiento del Río Torrente Frigio. Understand "agua" or "torrente" as the Torrente Frigio. Instead of drinking the Torrente Frigio, say "Está tan frío que puedes sentir cada diente infividual en toda tu mandíbula." The Torrente Frigio is aire.[2]
The Riverbed Course is a region. Vado del Torrente Frigio, the Vertiente and the Nacimiento del Río Torrente Frigio are in the Riverbed Course.
Rule for calculating combat modifiers of the player: if the location is in the Riverbed Course, modify to-hit roll by -3 for "por tener tus piernas en el agua"; continue the activity.
For calculating saving roll modifiers of the player:
if the location is in the Riverbed Course and we are going south,
modify to-save roll by 10 for "chapoter de vuelta por donde viniste";
continue the activity.[3]
Instead of swimming in the Riverbed Course, say "El agua es demasiado poco profunda para nadar; puede ser vadeada muy fácilmente, así que siéntete libre de andar de aquí para allá."
Swimming is an action applying to nothing.
Understand "nada" as swimming.
Report swimming: say "No hay agua suficiente en la que nadar."
Instead of going nowhere from the Vado del Torrente Frigio, say "La calle, por supuesto, va de norte a sur; las aguas poco profundas pasan por encima desde el noroeste hacia el sureste."
The Vertiente is northwest of Vado del Torrente Frigio. "El Torrente Frigio va desde el oeste hacia el sureste por un corte tan profundo que casi fluye bajo tierra." The impredecible y majestuoso afloramiento rocoso is in the Vertiente. The afloramiento rocoso is fixed in place. "En el centro de la corriente hay un alarmantemente impredecible, aunque majestuoso, afloramiento rocoso. Debe de ser más antiguo que el río, incluso más antiguo que la ciudad." The description is "Una especie de colina rocosa que puedes tratar de ascender. Desprende una sensación de paz inusitada."
Instead of going up in the Vertiente, say "Tienes que escalar el afloramiento."
Before climbing the majestuoso afloramiento for the first time, say "Advertencia: podrías ser capaz de escalarlo, pero incluso el intentarlo te costará fuerza." instead.
Instead of climbing the majestuoso afloramiento:
if the strength of the player < 3, say "Estás demasiado débil físicamente como para intentarlo." instead;
decrease the strength of the player by 1;
if a saving roll of 15 by the player to "escalar el impredecible afloramiento" is made
begin;
move the player to the Santuario del Pináculo;
otherwise;
say "Tu intento falla, y aterrizas con un irritante chapoteo; el agua es poco profunda y el cauce del río inquebrantable.";
end if.
The Santuario del Pináculo is a room. "La achatada cima del majestuoso afloramiento es, a la vez, severamente plano y sin duda sagrado. Sientes que debe de ser un lugar consagrado a alguno de los dioses de la antigua ciudad."
Instead of praying, say "El ruego a los dioses estaría degradado al hacerlo en un lugar como este."
Instead of praying in the Sanctum Sanctorum, say "Este es el lugar donde uno viene a esconderse de los dioses."
Instead of praying in the Santuario del Pináculo, say "Te preparas con debida solemnidad, y aún así, aún así: sientes que te faltan las palabras apropiadas a usar, si es que quieres que la oración sea respondida."
Praying is an action applying to nothing.
Understand "reza" as praying.
Understand "recita tus oraciones pequeno" as a mistake ("Buena idea, pero eso en sí no es una oración.")
Understand "fuera los dias desolados de tiempo anegado" as a mistake ("Buen intento, pero parece ser que esa no es una oración apropiada para este lugar. No ocurre nada.")
Praying to clouds is an action applying to nothing. Understand "vosotras nubes libres viajeras estad conmigo" as praying to clouds. Check praying to clouds: if the location is not the Santuario del Pináculo, say "Nada ocurrirá aquí." instead. Carry out praying to clouds: if the player does not know misil mágico, award 12 points; now the player knows misil mágico. Report praying to clouds: say "Entras en comunión con este lugar especial. El claro cielo otoñal se llena de nubes que se arremolinan alrededor. Te sientes pleno de propósito y habilidad."
Instead of going down in the Santuario del Pináculo:
if a saving roll of 15 by the player to "bajar con seguridad del afloramiento rocoso" is made
begin;
say "Respiras aliviado, y entonces siseas un poco cuando el Torrente Frigio te recuerda lo helada que está el agua de la montaña.";
otherwise;
say "Caes al descender, tomando ";
let the damage be the roll of 1d6+1;
say " puntos de daño; que aunque haya agua, es poco profunda y el cauce del río no perdona.";
decrease the strength of the player by the damage;
if the player is killed
begin;
end the game saying "Al caer te has matado";
end if;
end if;
move player to the Vertiente.
The Nacimiento del Río Torrente Frigio is west of the Vertiente. "El canal que sigue el fondo del profundo corte en la tierra se convierte en algo parecido a una cueva, ya que varias paredes de piedra pulimentada interrumpen el camino. Puedes vadear el río de vuelta hacia el este, ya que el resto de salidas son impracticables."
A reja de bronce is fixed in place in the Nacimiento del Río Torrente Frigio. "El Torrente Frigio nace aquí, atravesando una reja de bronce asegurada firmemente contra la roca de la cueva. Esperabas poder descender por aquí pero, no va a poder ser." Instead of opening the reja, say "Cuando dije 'asegurada firmemente', tenía en mente 'mucho más asegurada de lo que puedas romper con tus propias manos'." Instead of searching the reja, say "Agua. Montones de agua."
A goblin called Dronsh is in the Nacimiento del Río Torrente Frigio. "El Señor de los Goblins Dronsh, que estaba pescando aquí (¿quizás esto esté reservado sólo a las castas más altas?), se enfurece con tu mera presencia como siempre suelen hacer todos los goblins." Dronsh is carrying a lanza corta. Dronsh is carrying the llave de ocho patas. Dronsh has strength 12. Understand "goblin" and "lord" as Dronsh. Understand "señor de los goblins" as Dronsh.
[Los goblins son muy cuidadosos en mantener sus costumbres hospitalarias, se enfurecen con todos los extraños por igual.]
The description of the llave de ocho patas is "¿Qué estaría haciendo Dronsh con esto? No es de factura goblin. El aro al final de la llave está trabajado en hierro templado formando algún tipo de figura de ocho patas: sin valor, sin ser agradable a la vista, pero sin duda no es algo fácil de olvidar."[4]
Notes
[1]. La razón de esta advertencia es que los goblins son demasiado duros para acometerlos hasta que el jugador haya conseguido solventar las habitaciones anteriores; lo suficientemente bien como para tener el hechizo "hacer santuario", encontrar algo hecho de arcilla para usarlo como foco, y tener la suficiente fuerza como para realizar el conjuro. La pista es para indicar a los jugadores que deberían volver para terminar las habitaciones iniciales antes de proceder.
[2]. En un sentido metafísico. Hay una excusa - No creo que podamos llamarla explicación - en el falso magazine que acompaña el juego.